| |
どうもです。
返信遅れてすみません。
「ＭＳ ゴシック」「ＭＳ 明朝」の２択から選ぶという機能の実現方法ですが、
すみません、説明は時間がかかってしまうため省かせてください。
ひとまず以下の通りにしていただければ動くようになります。
(安定版は Beta4.5 ver 0.461/0.15、開発版はBeta4.7 ver 0.473/0.07 で動作確認をとっています)
また、これは開発版の次の更新で追加予定です。
まず、ERIS/Scene/CONFIG/ES_CONFIG.yst 内の一番下などに、
以下を追加してください。
//■[フォント・ゴシックor明朝選択ボタン] -----------------------------
//
#=ES.CONFIG.FONT.GMSEL.INIT
{
GOSUB[#=es.FONT.NAME.GET pint=@es.GSD(113,01)]
STR[$str=$_RSTR(1)]
IF[$str!="ＭＳ ゴシック" && $str!="ＭＳ 明朝"]
@es.GSD(113,01)=0
$es.GSD(113)="ＭＳ ゴシック"
GOSUB[#=ES.CONFIG.FONT.REF]
IFEND[]
IF[$str=="ＭＳ ゴシック"] \BT.ONOFF($es.BID,0,1) IFEND[]
IF[$str=="ＭＳ 明朝"] \BT.ONOFF($es.BID,1,1) IFEND[]
return[]
}
#=ES.CONFIG.FONT.GMSEL.ON
{
@es.GSD(113,01)=0;$es.GSD(113)="ＭＳ ゴシック"
GOSUB[#=es.FONT.NUM.GET]INT[@num=@_RINT(1)]
LOOP[SET=@num]
{
GOSUB[#=es.FONT.NAME.GET pint=@_LC]
IF[(@es.BNO==0 && $_RSTR(1)=="ＭＳ ゴシック") || (@es.BNO==1 && $_RSTR(1)=="ＭＳ 明朝")]
@es.GSD(113,01)=@_LC
$es.GSD(113)=$_RSTR(1)
LOOPBREAK[]
IFEND[]
}
LOOPEND[]
GOSUB[#=ES.CONFIG.FONT.REF]
return[]
}
そして、UserDesign/コンフィグ画面設計.txt の任意の位置に、
//----------------------------------------------------------------
//■ＭＳor明朝選択ボタン
//----------------------------------------------------------------
//◆ゴシック
\BT.GROUP(3)
\BT.RADIO(9991)
\BT.CGSYS("config/btn_gothic")
\BT.XY(000, 000)
\BT.Z(1000)
\BT.SET(FONT.GMSEL, 0)
//◆明朝
\BT.GROUP(3)
\BT.RADIO(9991)
\BT.CGSYS("config/btn_mincho")
\BT.XY(100, 000)
\BT.Z(1000)
\BT.SET(FONT.GMSEL, 1)
と追加していただき、(\BT.GROUP番号(どのタブページに表示するか)や\BT.XY座標は適当にいじってください)
cgsys/config フォルダ内に、
btn_gothic_off.png
btn_gothic_over.png
btn_gothic_on.png
btn_mincho_off.png
btn_mincho_over.png
btn_mincho_on.png
の名前でそれぞれボタン画像を用意してください。
これで動くかと思います。
>失礼いたします。
>いつもお答えいただいて、本当にありがとうございます。
>
>今回は、使用フォントの選択を、
>固定の種類から選ばせる、と言うことが出来るかどうか、
>お伺いしたいと思います。
>
>現在、サンプルの方では各マシンにインストールされているフォントリストから、
>任意のフォントを選ばせる、と言う形になっていると思いますが、
>それを例えば、
>「ＭＳゴシック」or「ＭＳ明朝」のどちらかを、
>コンフィグ内にてボタンで選択させる、
>と言う形にしたいと考えております。
>
>フォーラムの記事を参考に、2択ボタンを新規作成して、
>コンフィグに配置しているのですが、
>フォントの指定の仕方が具体的にわからずに困っております。
>
>現在、ES_CONFIG.ystの中で、ボタン制御の最後にGOSUBを使ってIF文に飛ばし、
>その中で判定をさせようとしているのですが、
>FONT[NAME="ＭＳ 明朝"]や$T(36,11)="ＭＳ 明朝"を使っても、
>どうにもフォントの指定がうまくできません。
>
>フォントの指定の仕方など、すみませんがお教えいただけませんでしょうか？
>
>お忙しい所すみませんが、なにとぞよろしくお願いいたします。
|
|
|
- 2012/4/27(金) 22:04 -