| |
>お世話になっております。
>
>初心者の質問で申し訳ないのですが、
>コンフィグ画面でSE2のみの音量設定をできるようにはならないでしょうか。
>
>SEとSE2の音量を分けて、プレイヤーが調整できるようにしたいのです。
>
>方法がございましたら、教えていただけますと幸いです。
まだ正式命令としては公開していないのですが、
β4以降であれば \SE 命令（効果音命令）の他に
\ESE 命令（環境効果音命令）というのが用意されていまして、
そちらを利用することで可能になります。
このあたり近い将来公開する予定なので、ちょうどいい機会ですので
現時点で \ESE を使用できるようにERISを改造する方法を説明します。
まず、コンフィグ画面設計.txt 内の任意の位置に
以下を追加して、画像ファイル、ボタングループ番号、座標等を調整してください。
//----------------------------------------------------------------
//■環境効果音音量
//----------------------------------------------------------------
//◆目盛り・土台
\BT.GROUP(4)
\BT.CGSYS("config/tip_gauge_base")
\BT.XY(362, 092+35*3)
\BT.Z(1000)
\BT.SET(VOL.ESE.GAUGE.BASE)
//◆目盛り
\BT.GROUP(4)
\BT.CGSYS("config/tip_gauge")
\BT.XY(362+8, 092+35*3+2)
\BT.Z(1001)
\BT.SET(VOL.ESE.GAUGE)
//◆ツマミ
\BT.GROUP(4)
\BT.CGSYS("config/btn_slider")
\BT.XY(362+8-5, 092+35*3+1) //スライダー左端の座標をセットする
\BT.Z(1002)
\BT.SLIDE(254,0) //スライダーの動く範囲XY
\BT.SET(VOL.ESE.SLIDER)
//ミュートボタン
IF[1] //チェックボタンの場合
{
//◆チェックボタン
\BT.GROUP(4)
\BT.CGSYS("config/btn_mute")
\BT.XY(320, 092+35*3-2)
\BT.Z(1000)
\BT.SET(VOL.ESE.MUTE, 1)
}
ELSE[] //ON,OFFボタンの場合
{
//◆ON
\BT.GROUP(4)
\BT.RADIO(089)
\BT.CGSYS("config/btn_on_bt3")
\BT.XY(300, 092+35*3)
\BT.Z(1000)
\BT.SET(VOL.ESE.MUTE, 0)
//◆OFF
\BT.GROUP(4)
\BT.RADIO(089)
\BT.CGSYS("config/btn_off_bt3")
\BT.XY(300, 092+35*3)
\BT.Z(1000)
\BT.SET(VOL.ESE.MUTE, 1)
}
IFEND[]
次に、「UserDefine\音量定義.txt」を開き、
任意の位置に
//---------------------------------------------------------------------
// 環境効果音音量【コンフィグ指定値】(初回起動時にセットされる)
//---------------------------------------------------------------------
@T(27,13)=256 // 0〜256
//---------------------------------------------------------------------
// 環境効果音スクリプト開始時ベース音量(スクリプト開始時にセットされる)
//---------------------------------------------------------------------
@T(12,13)=256 // 0〜256
を追加してください。
次に、「ERIS\es.GSD.yst」を開き、
1048〜1049行目付近(β4.0の場合は972行目付近)に
@es.LSD(001,13) = 256 //ESE全体1
という行がありますので、
@es.LSD(001,13) = @T(12,13) //ESE全体1
に置き換えてください。
最後に、「ERIS\Scene\CONFIG\ES_CONFIG.yst」を開き、
644〜649行目付近に
#=ES.CONFIG.VOL.ESE.SLIDER.VDEF { @es.GSD(001,13)=256;return[] }
という行がありますので、
#=ES.CONFIG.VOL.ESE.SLIDER.VDEF { @es.GSD(001,13)=@T(27,13);return[] }
に置き換えてください。
これで完了です。
あとはスクリプト中から、
\ESE(se001)
と記述していただければ、(パラメータは \SE と同じです)
\SE とは別の音量設定で再生されます。
またコンフィグに追加された音量設定スライダーで音量設定が可能です。
ただ、環境効果音の仕様として、デフォルトが「ループ再生」となります。
ですので、もしループ再生させたくない場合は、
\ESE(se001,,,1)
と指定して１回再生にしてください。
|
|
|
- 2012/8/4(土) 18:55 -