| |
>初心者な質問で申し訳ありません。
>パーツを１つずつ集めていく目的のゲームで、章と章の合間に『ここまで集まったよ』という目安のページを作りたいのですが、難航しています。
>図で表すと、
>× ○ × ×
>× × × ×
>× × × ○
>こういうイメージで×がまだ手に入れていないパーツ、○が手に入れたパーツというような具合です。
>http://yu-ris.net/forum/c-board.cgi?cmd=ntr;tree=655;id=question
>こちらのページを参考にしたのですが、背景のみのページを作る事は出来たのですが、ボタンというかパーツの○×を表す画像を並べる・それらを変数によって○・×に変化させる方法がわかりません。
>クリックで次の章に移るようにしたいのですが、\WAも無効になるために躓いてしまいました。
>どうか、宜しくお願いします。
どうもです。
これは変数を使用して場合分けすれば可能かと思われます。
例えばサンプルとして、３個の○×を表示する方法について説明します。
変数は適当に @L(101)〜@L(103) を使うとします。
まず、１個めの○×について、
@L(101) の値が 0 ならば「×」、 1 ならば「○」の画像を
場合分けを用いて表示させるようにします。
ファイルは 汎用選択肢画面設計.txt をいじります。
下のようになります。
IF[@L(101)==0]
\BT.CGSYS("select/batsu")
\BT.XY(100, 100)
\BT.Z(100)
\BT.SET(TIP.TIP_01)
IFEND[]
IF[@L(101)==1]
\BT.CGSYS("select/maru")
\BT.XY(100, 100)
\BT.Z(100)
\BT.SET(TIP.TIP_01)
IFEND[]
これを、表示したい個数分作成します。(サンプルとして今回は３個)
/////////////////////////// 1個目
IF[@L(101)==0]
\BT.CGSYS("select/batsu")
\BT.XY(100, 100)
\BT.Z(100)
\BT.SET(TIP.TIP_01)
IFEND[]
IF[@L(101)==1]
\BT.CGSYS("select/maru")
\BT.XY(100, 100)
\BT.Z(100)
\BT.SET(TIP.TIP_01)
IFEND[]
/////////////////////////// 2個目
IF[@L(102)==0]
\BT.CGSYS("select/batsu")
\BT.XY(200, 100)
\BT.Z(100)
\BT.SET(TIP.TIP_02)
IFEND[]
IF[@L(102)==1]
\BT.CGSYS("select/maru")
\BT.XY(200, 100)
\BT.Z(100)
\BT.SET(TIP.TIP_02)
IFEND[]
/////////////////////////// 3個目
IF[@L(103)==0]
\BT.CGSYS("select/batsu")
\BT.XY(300, 100)
\BT.Z(100)
\BT.SET(TIP.TIP_03)
IFEND[]
IF[@L(103)==1]
\BT.CGSYS("select/maru")
\BT.XY(300, 100)
\BT.Z(100)
\BT.SET(TIP.TIP_03)
IFEND[]
※2個目、3個目は、@L(101)も @L(102)、@L(103) と変えてください。
また、ボタン名も「TIP.TIP_02」「TIP.TIP_03」と変えてください。
あとは表示座標もそれぞれ変えてください。
あとはシナリオスクリプト上で、
@L(101)=1
@L(102)=1
@L(103)=0
とすれば、○、○、× と表示されるかと思います。
あとは、クリックしたら次に進む方法ですが、
これは画面中のどこをクリックしても進む、ということでしょうか。
それでしたらば、
『ショートカットキーとして左クリックを、「BTN.SEL」の1番のボタンに割り当ててしまう』
ことで、可能になります。
「BTN.SEL」の1番のボタンの定義を、
\BT.NAME("■選択肢画像１")
\BT.CGSYS("select/btn_sel01_off", "select/btn_sel01_over")
\BT.XY(9999, 9999) //※絶対に表示されない位置に表示するように設定する
\BT.Z(10)
\BT.KEY(MOUSE_L) //ショートカットキーとして 左クリック を割り当てる
\BT.SET(BTN.SEL, 01)
とすることで、
選択肢画像は座標が(9999,9999)なので画面内には表示されないものの、
ショートカットキー(左クリック)は有効なので、
左クリックすると「選択肢1」が選択されたことになり、
画像選択肢画面が終了して次に進むことになります。
ただ、画像は必ずダミーでもいいので必ず用意しておいてください。
どうせ表示されないからといって画像指定を省略してしまうと、
ボタン自体が機能しなくなってしまいます。
こんな感じでしょうか。
参考になれば幸いです。
|
|
|
- 2013/5/27(月) 1:05 -
